<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="onComplete()">
	<mx:Script>
		<![CDATA[
			import flash.utils.getDefinitionByName;
			import flash.net.registerClassAlias;
			import flash.utils.getQualifiedClassName;
			import com.Person;
			import mx.utils.ObjectUtil;
			
			protected function onComplete():void
			{
				/*-------------------------------------
				Case 1: assigning object 1 to object 2
				---------------------------------------*/
				var obj1:Object = {firstName:"John", lastName:"Doe", age:35};
				
				// The assignment acts on the references: obj1 and obj2 are
				// 2 references that point to the same memory location
				var obj2:Object = obj1;
				
				// Modifying the age attribute of obj1, we affect also obj2
				obj1.age = 45;
				
				// traces "obj1 age: 45 obj2 age: 45"
				trace("obj1 age: " + obj1.age + " obj2 age: " + obj2.age);
				
				/*-------------------------------------
				Case 2: using the copy method
				---------------------------------------*/
				// With the copy method the object memory location is copied, 
				// obj1 and obj3 references point to different memory locations 
				var obj3:Object = ObjectUtil.copy(obj1);
				
				obj1.firstName = "Ken";
				
				// traces "obj1 first name: Ken obj2 first name: John"
				trace("obj1 first name: " + obj1.firstName + " obj3 first name: " + obj3.firstName);
				
				var pers1:Person = new Person();
				pers1.firstName = "Lisa";
				pers1.lastName = "Redcliff";
				pers1.age = 25;
				
				// 1.
				//var pers2:Person = ObjectUtil.copy(pers1) as Person;
				// 2.				
				var pers2:Person = copyObject(pers1) as Person;
				
				// Statement 1 
				// ------------
				// throws an error
				//
				// Statement 2
				// ------------
				// traces "pers1 last name:  Redcliff pers2 last name: Redcliff"
				trace("pers1 last name: " + pers1.lastName + " pers2 last name: " + pers2.lastName);
			}
			
			/*
				The copyObject method calls the copy function only when
				the class is registered, so the ByteArray deserialization
				can be done correctly.
			*/
			public function copyObject(sourceObj:Object):Object
			{
				var className:String = getQualifiedClassName(sourceObj);
				registerClassAlias(className, getDefinitionByName(className) as Class);
				
				return ObjectUtil.copy(sourceObj);
			}
			
		]]>
	</mx:Script>
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" 
	creationComplete="onComplete()">
	<mx:Script>
		<![CDATA[
			import mx.events.ResourceEvent;
			import mx.controls.Alert;
			import mx.collections.ArrayCollection;
			
			// The current locale: the default is en_US
			private var _currentLocale:String = "en_US";
			
			protected function onComplete():void
			{
				// On creation complete set the locale with a default (en_US)
				setupLocale(true);
			} 
			
			private function setupLocale(forceLoad:Boolean=false):void
			{
				// Check if the resource is already loaded.
				// The forceLoad flag is used to force the loading even if the resource has
				// already been imported.
				// During the initialization, the en_US loading has to be forced, because the
				// english language is automatically included by Flex, but does not contain our
				// resource definitions. 
				if(resourceManager.getLocales().indexOf(_currentLocale) == -1 || forceLoad)
				{
					// If the resource has not been loaded yet, or forceLoad=true, load the resource module
					var dispatcher:IEventDispatcher = resourceManager.loadResourceModule(_currentLocale + "_resx.swf");
					// Attach an event listener which has to be called when the module is completely loaded
					dispatcher.addEventListener(ResourceEvent.COMPLETE, onResourceLoaded);
				}
				else
				{
					// If the resource has already been loaded, simply localize
					onResourceLoaded(null);
				}
			}
			
			/*
				The following variables represent the parameters that have to be localized.
			*/
			[Bindable]
			private var _comboLabelText:String;
			
			[Bindable]
			private var _welcomeText:String;
			
			[Bindable]
			private var _helloLabelText:String;
			
			[Bindable]
			private var _helloMessage:String;
			
			private function onResourceLoaded(e:ResourceEvent):void
			{
				// Set the locale chain 
				resourceManager.localeChain = [_currentLocale];
				
				// Modify the localization parameters
				_comboLabelText = resourceManager.getString("localizedContent","comboLabel");
				_welcomeText = resourceManager.getString("localizedContent","welcome");
				_helloLabelText = resourceManager.getString("localizedContent","helloLabel");
				_helloMessage = resourceManager.getString("localizedContent","helloMessage");
				
				
			}
			
			[Bindable]
			private var _langs:ArrayCollection = new ArrayCollection(
									[{name:"English", value:"en_US"}, 
									 {name:"Italiano", value:"it_IT"},
									 {name:"Francaise", value:"fr_FR"}]);
			
			private function onHelloClick():void
			{
				// The message displayed depends on the selected language
				Alert.show(_helloMessage);
			}
			
			private function onLangChange():void
			{
				// When the selected language of the combo box changes,
				// the corresponding module is loaded
				_currentLocale = langsCombo.selectedItem.value;
				setupLocale();
			}
		]]>
	</mx:Script>
	<mx:VBox>
		<mx:HBox>
			<mx:Label text="{_comboLabelText}" />
			<mx:ComboBox id="langsCombo" dataProvider="{_langs}" labelField="name" change="onLangChange()" />
		</mx:HBox>
		<mx:Label text="{_welcomeText}" />
		<mx:Button id="helloBtn" label="{_helloLabelText}" click="onHelloClick()" />
	</mx:VBox>
</mx:Application>