var loggedUser:String = "Fabio";
var localizedString:String = "-USER- has been kicked"

....

var myPattern:RegExp = /-USER-/g;  
localizedString.replace(myPattern, loggedUser);  // Output : Fabio has been kicked

var angle:Number = 0
var centerX:Number = 50
var centerY:Number = 50;
var radius:Number = 22;
var speed:Number = 0.1
 
var circle:Shape = new Shape();
addChild(circle)
circle.graphics.beginFill(0x00FF00);
circle.graphics.moveTo(centerX, centerY);
 
function onEnterFrame(e:Event) {
 
 if (angle > 2 * Math.PI)
  this.removeEventListener(Event.ENTER_FRAME, onEnterFrame)
 
 trace("angle", angle)
 circle.graphics.lineTo(centerX + Math.cos(angle) * radius,
             centerY + Math.sin(angle) * radius);
 
 angle += speed;
}
this.addEventListener(Event.ENTER_FRAME, onEnterFrame)

<?xml version="1.0" encoding="utf-8"?>
<mx:Application 
	xmlns:mx="http://www.adobe.com/2006/mxml" 
	layout="absolute"
	creationComplete="init(event)" >


	<mx:Script>
		<![CDATA[
		
			import mx.events.FlexEvent;
			
			private const NOME_UTENTE:String = "Fabio Biondi";
			
			private function init(evt:FlexEvent):void
			{
				phpRPC.url="assets/Es02_CheckUser.php";
				phpRPC.send({ utente: NOME_UTENTE} )
			}


			private function viewEmail():void
			{
				outputArea_txt.text = phpRPC.lastResult.email
			}
			
		]]>
	</mx:Script>
	
	
	<mx:HTTPService 
		id="phpRPC" 		
		resultFormat="flashvars"
		result="viewEmail()"
		/>


	<mx:TextArea 
		id="outputArea_txt" y="20"/>


</mx:Application>


// PHP CODE
<?php

   switch($_REQUEST['utente'])
   {
    case "Fabio Biondi":
      echo "email=info@fabiobiondi.com";
      break;
      
    default:
      echo "email=User not found";
      break;
    }
   
?>

// AS3 Version
package com.domain.ui
{
	import mx.containers.VBox;

	public class VBoxLabeledAS extends VBox
	{
		import mx.controls.HRule;
		import mx.controls.Label;
		
		[Bindable]
		private var _label:String;
		
		public function VBoxLabeledAS()
		{
			super();
			this.setStyle('backgroundColor', 0x999999)
		}
		
		public function set labelVBox(val:String):void {
			
			
			// Create Title Label
			var label:Label = new Label();
			addChild(label)
			label.text = val;
			
			// Create HRule
			var hr:HRule = new HRule();
			addChild(hr)
			hr.percentWidth = 100;
			
		}
		
		
		
	}
}


//MXML Version
<?xml version="1.0" encoding="utf-8"?>
<mx:VBox xmlns:mx="http://www.adobe.com/2006/mxml"
	 width="100%" height="100%"
	 backgroundColor="#999999"
	>	
	<mx:Script>
		<![CDATA[
			import mx.controls.HRule;
			import mx.controls.Label;
			
			[Bindable]
			private var _label:String;
			
			public function set labelVBox(val:String):void {
				
				
				// Create Title Label
				var label:Label = new Label();
				addChild(label)
				label.text = val;
				
				// Create HRule
				var hr:HRule = new HRule();
				addChild(hr)
				hr.percentWidth = 100;
				
			}
		]]>
	</mx:Script>
	
	
</mx:VBox>

<?xml version="1.0" encoding="utf-8"?>
<mx:VBox xmlns:mx="http://www.adobe.com/2006/mxml" width="300" height="100"
	styleName="container" currentState="closed">
	
	
	<mx:Script>
		<![CDATA[
			import mx.effects.easing.Back;
			import mx.effects.easing.Bounce;
			
			private function onChangerClick( event:Event ) : void {
				
				currentState = ( currentState == "open" ) ? "closed" : "open";
				
			}
	]]>
	</mx:Script>
	
	
	

	<!--STATES-->
	<mx:states>
		<mx:State name="open">
			<mx:SetProperty name="height" value="450"/>
			<mx:SetProperty target="{changeStatusButton}" name="label" value="Close"/>
		</mx:State>
	
		<mx:State name="closed">
			<mx:SetProperty target="{this}" name="height"
					value="100" />
		</mx:State>
	</mx:states>
	
	
	
	
	<!--TRANSITIONS-->
	<mx:transitions>
	
		<!--Define the transition from 'open' to 'closed' state -->
		<mx:Transition fromState="open" toState="closed">
		
			<!--Parallel Transition-->
			<mx:Parallel duration="500">
			
				<!--Define RESIZE transition attributes specifing the target (the whole component)-->	
				<mx:Resize target="{this}"
					easingFunction="{mx.effects.easing.Bounce.easeOut}" 
					duration="1500"/>
			</mx:Parallel>
			
		</mx:Transition>
			
			
		<!--Define the transition from 'close' to 'open' state -->
		<mx:Transition fromState="closed" toState="open">
		
			<mx:Parallel duration="500">
				<mx:Resize target="{this}"
					easingFunction="{mx.effects.easing.Back.easeOut}"
					duration="1000" />
			</mx:Parallel>
			
		</mx:Transition>
	</mx:transitions>
	
	
	
	<mx:Button id="changeStatusButton" label="Open"
		click="onChangerClick(event);" />
	
</mx:VBox>

package events
{
	
  import flash.events.Event;
  
  public class CustomEvent extends Event
  {
  	public static const FORM_SUBMITTED:String = "FormSubmitted"
  	
    public var name:String;
    public var surname:String;
    
    public function CustomEvent( _type:String, _userName:String, _surName:String):void
    {
      super(_type);
      this.name = _userName;
      this.surname = _surName;
    }
    
    
    override public function clone():Event 
    {
       return new CustomEvent(type, name, surname);
    }
  }
}

PrivatyLabel.htmlText = privacyLabel // retrieved from a previous XML loader (see description above)
PrivatyLabel.addEventListener(TextEvent.LINK, methodToCall);

public function methodToCall(e:TextEvent):void
{
  // actions here
}

// String to Find
var stringToFind:String = "Flash Media";

// XML Object
var myXML:XML = 
    <order>
        <item id='101'>
            <title>Technologies</title>
            <desc>XML e4x rulez</desc>
        </item>

	<item id='102'>
            <title>Adobe Products</title>
	    <desc>Flex, Flash, Air, FlashLite, Catalyst, Flash Media Server 2, ... </desc>
        </item>
		
		
	<item id='103'>
            <title>Server Side Products</title>
	    <desc>Flash Media Server 3, Flash Collaborative Service, ColdFustion</desc>
        </item>
		
    </order>


// Loop over the XML items
for (var i:uint = 0; i < myXML.item.length(); i++)  {
	
	// Get the item description
	var tempString:String = myXML.item.desc 
	
	
	/*
	* Check if the defined word does exist in the description, displaying:
	* - Node title
	* - Node ID
	* - XML node index (from 0 to N)
	* - The searched word
	*/	
	if (tempString.search(stringToFind) != -1) {
		// This trace displays:
		// ---> Adobe Products ( ID - 102 ) contains this word: 'Flash Media' (XML item index: 1 )
		// ---> Server Side Products ( ID - 103 ) contains this word: 'Flash Media' (XML item index: 2 )
		trace("--->",  myXML.item.title, "( ID -",  myXML.item.@id, ") contains this word: '" + stringToFind + "' (XML item index:", i, ")")
	}
								  
								  
}

import fl.managers.StyleManager;
import fl.controls.Button

// Set a global textFormat for every Button Component
var tf:TextFormat= new TextFormat();
tf.color = 0x0000FF;
tf.size = 16;
StyleManager.setComponentStyle(Button, "textFormat", tf);

// Set a global style property for every Button Component
var styleProperty:String = "textPadding";
var value:Number = 30;
StyleManager.setComponentStyle(Button,styleProperty,value);    

<?xml version="1.0" encoding="utf-8"?>
<!--
Use Google Search Bouleaver API 
http://labs.boulevart.be/index.php/2008/12/15/google-as3-api/
-->
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" width="600" height="500">
	
	<mx:Script>
		<![CDATA[
			import be.boulevart.google.ajaxapi.translation.GoogleTranslation;
			import com.adobe.utils.StringUtil;
			import be.boulevart.google.ajaxapi.search.web.GoogleWebSearch;
			import be.boulevart.google.ajaxapi.search.web.data.GoogleWebItem;
			import be.boulevart.google.ajaxapi.search.GoogleSearchResult;
			import be.boulevart.google.events.GoogleApiEvent;
			
			private var start:int=0
			private var max:int=0
			private var lang:String="" 
			private var __results:Array
			
			private function searchWeb():void{
				var google:GoogleTranslation = new GoogleTranslation()
			
				var googleWebSearch:GoogleWebSearch
				
				// Only first time
				if(max==0){
					
					// Max result to get 
					max=nmsResults.value
					__results=new Array()
					
					// Trim() method removes whitespace from the front and the end of the specified
					if(StringUtil.trim(txtInput.text).length){
						
						// If italian radioButton is selected
						if(optItalian.selected){
							lang="it"
						}
						
						// Start a new Search and waiting for a response
						googleWebSearch = new GoogleWebSearch()
						googleWebSearch.search(txtInput.text,0,lang)
						googleWebSearch.addEventListener(GoogleApiEvent.WEB_SEARCH_RESULT,onWebResults)
					}
				}else{
					// Start a new Search and waiting for a response
					googleWebSearch = new GoogleWebSearch()
					googleWebSearch.search(txtInput.text,start,lang)
					googleWebSearch.addEventListener(GoogleApiEvent.WEB_SEARCH_RESULT,onWebResults)
				}
			}
			
			private function onWebResults(e:GoogleApiEvent):void{
				var stop:Boolean=false
				var resultObject:GoogleSearchResult=e.data as GoogleSearchResult
				
				trace("Estimated Number of Results: "+resultObject.estimatedNumResults)
				trace("Current page index: "+resultObject.currentPageIndex)
				trace("Number of pages: "+resultObject.numPages)			
				
				// Loop over the result  
				for each (var result:GoogleWebItem in e.data.results as Array){
					trace(result.title,result.url)
					start++
					if(start <= max){		
						__results.push(result)
					}else{
						stop=true
					}
				}
				
				// make a new search if start < Max 
				if((start<=(max)) && !stop){
					searchWeb()
				}
				
				if(stop){
					// Populate dataProvider
					webResultsView.dataProvider=__results
					max=0
					lang=""
					start=0
				}
			}
			
		]]>
	</mx:Script>
	
	
	<mx:HBox>
		<mx:TextInput width="293" id="txtInput" text="ActionScript.it"/>
		<mx:NumericStepper minimum="3" id="nmsResults" stepSize="1" value="15" maximum="30"/>
		<mx:Button label="go" click="searchWeb()" />	
	</mx:HBox>	
	
	<mx:CheckBox label="search Italian sites only" id="optItalian"/>
	
	<mx:TileList height="350" id="webResultsView" rowHeight="120" columnWidth="500"
		columnCount="1" right="10" left="10" top="50" bottom="10"
		itemRenderer="WebItem"></mx:TileList>
		
		
</mx:Application>

package com.fabiobiondi.utils {
 
    import flash.external.ExternalInterface;
 
    public class URLUtil    {
 
	/**
	 * Open a popup window
	 * @param	url			link to open
	 * @param	target		window target
	 * @param	options 	popup options
	 * 
	 */
        public static function openWindow( url : String, 
        				    target : String = "_blank", 
        				    options : String = "") : void {
 
            ExternalInterface.call("window.open", url, target, options);
        }
 
 
	/**
	 * Get the Browser Type
	 * @Return the userAgent property	
	 * 
	 */
	public static function checkBrowser():String {
 
		var userAgent:String = 
			String(ExternalInterface.call("function() {return navigator.userAgent;}"));
 
		return userAgent;
 
 
	}
 
 
    }
 
}

<?php
       readfile($_REQUEST["url"]);
?>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical"
	backgroundColor="#999999">

	<mx:Script>
		<![CDATA[
			
			// The Custom Image for the Slider Thumb 
			[Embed(source="assets/slider/slider_arrow.png")]
	    		public static const SLIDER_ARROW:Class;
	    
		]]>
	</mx:Script>
	
	
	
	<!--  STANDARD SLIDER  --> 
	<mx:HSlider width="100" height="1"
	 			 liveDragging="true"
	 			 />			
	 			 
	<mx:Spacer height="70" />
	
	
	<!--  SLIDER  WITH CUSTOM SKINS  --> 
	<mx:HSlider width="100" height="1"
	 			 trackSkin="skins.IconSliderTrack"
	 			 thumbSkin="{SLIDER_ARROW}"
	 			 sliderThumbClass="skins.IconSliderThumb"
	 			 liveDragging="true"
	 			 />
	
	
</mx:Application>



//==============================================================================
//skins/IconSliderTrack.as
//==============================================================================
package skins
{   
    import mx.core.UIComponent;   
  
    public class IconSliderTrack extends UIComponent   
    {   
           
        /**
        * Modify the default track layout
        * 
        */
        override protected function updateDisplayList(unscaledWidth:Number,
unscaledHeight:Number):void{   
            super.updateDisplayList(unscaledWidth, unscaledHeight);   
  			this.graphics.moveTo(0,0);   
            this.graphics.lineStyle(5,0x656565);   
	        
	        // Draw a curve instead of the classic line 
	      	this.graphics.curveTo(unscaledWidth, 40, unscaledWidth, 0)
	        
	        // Draw a Bold Line 
	        // NOTE: if you want to use this comment the previous line 
	        //this.graphics.lineTo(unscaledWidth,0);
	        
        }   
    }   
} 


//==============================================================================
//skins/IconSliderThumb.as
//==============================================================================
package skins {
	
    import mx.controls.sliderClasses.SliderThumb;

    public class IconSliderThumb extends SliderThumb {
        
        public function IconSliderThumb() {
            super();
            
            /**
            *  You need to manually update the thumb width 
            *  and height to the Thumg image dimensions,
            *  otherwise its displayed size won't be right.
            *  NOTE: try to comment following line to see the result 
            */             
            this.width = 36;
            this.height = 35;
            this.buttonMode = true;
        }
    }
}

<?xml version="1.0"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" xmlns:maps="com.google.maps.*" 
	layout="absolute" 
	width="100%" height="100%" >
  

   <mx:Script>
       <![CDATA[
       	import mx.events.ListEvent;
        import com.google.maps.interfaces.IPolyline;
        import com.google.maps.Map;
        import com.google.maps.MapEvent;
        import com.google.maps.LatLng;
        import com.google.maps.LatLngBounds;
        import com.google.maps.overlays.Marker;
        import com.google.maps.overlays.MarkerOptions;
        import com.google.maps.controls.ControlPosition;
        import com.google.maps.controls.MapTypeControl;
        import com.google.maps.services.*;
        import com.google.maps.MapAction;
        
        import mx.controls.Alert;
        import mx.collections.ArrayCollection;
            
        private var dir:Directions;
        
        
        /**
        * This method is called when the default Map is loaded 
        * 
        */
        private function onMapReady(event:Event):void {
            setupDirections();
            controlPanel.enabled = true;
        }
        
        /**
        * Define Direction class and its listeners 
        * 
        */
        private function setupDirections():void {    
        	
            dir = new Directions();
            dir.addEventListener(DirectionsEvent.DIRECTIONS_SUCCESS, onDirLoad);
            dir.addEventListener(DirectionsEvent.DIRECTIONS_FAILURE, onDirFail);
        }
        
        
        /**
        * Start a GMap Call to get distance between the selected store city and the user city 
        * 
        */
        private function processForm(event:ListEvent=null):void {
        	
        	// Set Directions Options (see GMAP API doc for properties details)
            var opts:DirectionsOptions = new DirectionsOptions({locale: "English", travelMode: "driving", avoidHighways: false})
            dir.setOptions(opts);
            
            // GMAP Query: From ... To ... 
            dir.load("from: " + from.text + " to: " + storeCities.selectedItem.data);
            
            // Disable query panel
            controlPanel.enabled = false;
        }
            
        /**
        * Direction Wrong Query (i.e. a city wasn't found in the db)  
        * 
        */
        private function onDirFail(event:DirectionsEvent):void {
              Alert.show("Status: " + event.directions.status);
              controlPanel.enabled = true;
        }
        
        /**
        * Direction Query SUCCESSFULLY   
        * 
        */
        private function onDirLoad(event:DirectionsEvent):void {
        	
        	// Enable Query Panel
        	controlPanel.enabled = true;
        	
        	// Get Direction object
            var dir:Directions = event.directions;
            
            // Clear previous displayed directions 
            map.clearOverlays(); 
            
            // Display Directions on Map
            var directionsPolyline:IPolyline = dir.createPolyline();
            map.addOverlay(directionsPolyline);
            var directionsBounds:LatLngBounds = directionsPolyline.getLatLngBounds();
            
            // Fix map position
            map.setCenter(directionsBounds.getCenter());
            map.setZoom(map.getBoundsZoomLevel(directionsBounds));
       
       		// Display Markers (start and destination) 
            var numRoutes:Number = dir.numRoutes;
            var startLatLng:LatLng = dir.getRoute(0).getStep(0).latLng;
            var endLatLng:LatLng = dir.getRoute(numRoutes-1).endLatLng;
            map.addOverlay(new Marker(startLatLng));
            map.addOverlay(new Marker(endLatLng));
            
            // Display trip info
            infoTripTxt.htmlText = dir.summaryHtml;
        }
            
        

       ]]>
   </mx:Script>
   
   
   <!--DEBUG KEY: you need to sign up for your own key-->
   <maps:Map 
    id="map" 
    key="ABQIAAAA7QUChpcnvnmXxsjC7s1fCxQGj0PqsCtxKvarsoS-iqLdqZSKfxTd7Xf-2rEc_PC9o8IsJde80Wnj4g" 
    mapevent_mapready="onMapReady(event)"
    width="100%" height="100%"/>

    
 
   <mx:VBox width="395" height="200" id="controlPanel" enabled="false"
 		backgroundAlpha="0.8" backgroundColor="#FFFFFF">
 		
	  <mx:HBox width="100%">
		   <mx:Label text="From (write your city):" fontWeight="bold"/>
		   <mx:TextInput
		     id="from"
		     text="Firenze"
		     width="100%" />
	  </mx:HBox>
	  
	  <mx:HRule width="100%" />
	  
	  <mx:Label fontWeight="bold"
		  text="To (select below the store and check the distance):"/>
			
	  	<mx:HBox width="100%" height="100%" verticalAlign="middle">
		    <mx:List id="storeCities" width="150"
		    	change="processForm(event)" height="121"> 
		        <mx:Object label="Milan - Outlet" data="Milan" />
		        <mx:Object label="Rome - Boutique" data="Rome" />
		        <mx:Object label="Napoli - Outlet" data="Napoli" />
		        <mx:Object label="Venezia - Shop" data="Venezia" />
		        <mx:Object label="Torino - Outlet" data="Torino" />
		    </mx:List>
		    
		    <mx:TextArea width="220" height="60" fontSize="14" id="infoTripTxt" 
		    	backgroundAlpha="0" borderStyle="none"/>	
		    
		</mx:HBox>

  </mx:VBox>

   
</mx:Application>

package {
	import flash.display.*;
	import flash.events.*;
	import flash.filters.BlurFilter;
	import flash.geom.ColorTransform;
	import flash.text.TextField;
	import flash.utils.getDefinitionByName;

	import com.flashdynamix.motion.*;
	import com.flashdynamix.motion.effects.*;
	import com.flashdynamix.motion.extras.Emitter;
	import com.flashdynamix.motion.layers.BitmapLayer;


	public class MenuEmitter extends Sprite {

		
		public var menuButton:MovieClip;

		private var emittor : Emitter;
		private var layer : BitmapLayer;
		
		private var ct : ColorTransform;
		private var bf : BlurFilter;

		private var tx : Number;
		private var ty : Number;

		public function MenuEmitter() {
			
	
			// Create a Bitmap Layer where we'll draw the Emitter and apply some effects
			layer = new BitmapLayer(900, 400);
			bf = new BlurFilter(10, 10, 2);
			layer.add(new ColorEffect(new ColorTransform(1, 1, 1, 0.9)));
			layer.add(new FilterEffect(bf));
			
			// Set quality to LOW to get better performance
			stage.quality = StageQuality.LOW;
			
			
			// The Emitter MovieClip "BluePrint"
			var Box : Class = getDefinitionByName("Box") as Class;
			
			// Emitter Creation
			ct = new ColorTransform(1, 1, 1, 1, -115, -30, 70);
			emittor = new Emitter(Box, null, 2, 1, "0, 360", "1, 110", 1, BlendMode.ADD);
			emittor.transform.colorTransform = ct;
			emittor.endColor = {redOffset:255, greenOffset:-10, blueOffset:-270, alphaOffset:-255};
			
			// We can't build the emitter on 0,0 because it will be cutted on the top and on the left side
			emittor.x = 150
			emittor.y = 150
			
			// Display on screen
			layer.draw(emittor.holder);
			menuButton.addChildAt(layer,0);
			
			// Stop emitter at startTime
			emittor.stop()

			// RollOver / RollOut on button
			menuButton.gfx.buttonMode = true;
			menuButton.gfx.addEventListener(MouseEvent.ROLL_OVER, onMenuRollOver)
			menuButton.gfx.addEventListener(MouseEvent.ROLL_OUT, onMenuRollOut)
			
			// ENTER_FRAME event
			// We'll update the emittor properties to generate random
			addEventListener(Event.ENTER_FRAME, update)
			
		}
		
		/**
		* Update emittor rotation properties to have different rotation for each particle
		*/
		private function update(e : Event) : void {
			emittor.rotation += 20;
		}
		
		/**
		* At Button rollOver start the emitter
		*/
		private function onMenuRollOver(e : MouseEvent) : void {
			emittor.start()
		}
		
		/**
		* At Button rollOut stop the emitter
		*/
		private function onMenuRollOut(e : MouseEvent) : void {
			emittor.stop()
		}
		
		
		
		

	}
}

package {
	
	import flash.display.MovieClip;
	import flash.display.Stage;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.display.StageDisplayState
	
	import fl.controls.Button;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.events.FullScreenEvent;


	public class FullScreenMain extends MovieClip {
		
		// The FullScreen Button
		private var fullScreen_btn:Button;
		
		// Save the fullScreen status
		private var fullScreenStatus:Boolean;		
		
		
		/**
		* Constructor
		*/
		public function FullScreenMain() {

			// Create the FullScreen Button (add to the .fla library the button component assets)
			fullScreen_btn = new Button();
			fullScreen_btn.label = "Enable FULL_SCREEN";
			fullScreen_btn.width = 150;
			fullScreen_btn.x = 120;
			fullScreen_btn.y = 50;
			addChild(fullScreen_btn)


			// Set NO_SCALE because we don't want that when fullscreen is enable movieclips are scaled too
			var swfStage:Stage = this.stage;
			swfStage.scaleMode = StageScaleMode.NO_SCALE;
			swfStage.align = StageAlign.TOP_LEFT;
			
			// Registriamo un listener per la modalitÃÆ’Æ’ÃÆââ‚

¬â„¢ÃƒÆ’†â€™ÃƒÂ¢Ã¢â€šÂ¬ ââ‚Ãââ‚

¬Å¡Ãƒâ€šÃ‚¬ÃƒÆ’¢â€žÂ¢  FULLSCREEN:

			// Listener for FullScreen Button
			fullScreen_btn.addEventListener(MouseEvent.CLICK, changefullScreenStatus)


			// Listener for FullScreen event. It's invoked every time the 'displayState' property change
			fullScreen_btn.stage.addEventListener(FullScreenEvent.FULL_SCREEN, fullScreenRedraw);
			

		}



	
	
		/**
		* Check the fullScreenStatus and Enabled / Disable the FullScreen
		*/
		private function changefullScreenStatus(e:MouseEvent):void 
		{
			// Disable FullScreen if enabled, and viceversa
			if(fullScreenStatus)
				fullScreen_btn.stage.displayState = StageDisplayState.NORMAL;
			else
				fullScreen_btn.stage.displayState = StageDisplayState.FULL_SCREEN;
				
		
		}
		
		/*
		* Invoked at every 'displayState' property change
		*/
		function fullScreenRedraw(event:FullScreenEvent):void
		{
			// Check if fullScreen is enabled and uptades properties
			if (event.fullScreen)
			{
				fullScreen_btn.label = "Disable FULL_SCREEN";
				fullScreenStatus = true;
			}
			else
			{
				fullScreen_btn.label = "Enable FULL_SCREEN";
				fullScreenStatus = false;
			}
		
		}
		
	
	}
}

// FLASH DOCUMENT CLASS
package {

	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.MouseEvent;
	import caurina.transitions.*
	import flash.display.DisplayObject;
	
	public class VideoMain extends Sprite
	{
		
		// Horizontal Gap between Video Thumbs
		private const HORIZONTAL_GAP:uint = 50;
		
		// Total of VideoThumbs to show
		private const VIDEO_TOTAL:uint = 6;
		
		// Thumbnails original Y position
		private const Y_POS:uint = 125;

		// Thumbnails original Z position
		private const Z_POS:uint = 550;
		
	
		
		public function VideoMain()
		{
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			
			// Create video thumbs
			for (var i:uint = 0; i < VIDEO_TOTAL; i++) {
				
				// Create a new VideoThumb istance 
				var thumb:VideoThumb = new VideoThumb();
				
				// Save original Index VideoThumb 
				thumb.originalIndex = i;
				
				// Set Thumb Position (x, y, z)
				thumb.x = thumb.originalX = HORIZONTAL_GAP * i 
				thumb.y = Y_POS
				thumb.z = Z_POS;
				
				// Set Thumb Rotation
				thumb.rotationY = -90;

				thumb.addEventListener(MouseEvent.CLICK, onClick)
				thumb.buttonMode = true;
				
				addChild(thumb)
			}
		}
		
		

		/**
		* Click Video MovieClip
		*/
		private function onClick(event:MouseEvent):void
		{
			// If clicked videoThumb is already opened
			if(event.currentTarget.isOpened) {
				
				// Back to the original position				
				Tweener.addTween(event.currentTarget, {
									   rotationY: -90 , 
							 		   x: event.currentTarget.originalX,
									   y: Y_POS,
									   z: Z_POS,									   
									   time:0.5, 
									   transition:"easeInOutSine",
									   onComplete: event.currentTarget.videoFLB.stop()});
			

				// Set depth to the original Position
				this.swapChildrenAt(getChildIndex(event.currentTarget as DisplayObject), event.currentTarget.originalIndex)
				
				
				
			} else {

				// Enlarge Video and PLay it when animation is completed
				Tweener.addTween(event.currentTarget, {
							 		   rotationY: 0 , 
							 		   x: 230,
									   y: 200,
									   z: 0,
									   rotationY: 0,
									   time:0.5, 
									   transition:"easeInOutSine",
									   onComplete: event.currentTarget.videoFLB.play()});

				// Bring to Front				
				this.swapChildrenAt(event.currentTarget.originalIndex, this.numChildren -1 )
				
			}
			
			
			// Change isOpened Status (to always know if a thumb is opened ) 
			event.currentTarget.isOpened = !event.currentTarget.isOpened;
			
		}
		
		
	}
}





// VideoThumb.as Class
package {


	import flash.display.MovieClip;

	
	public class VideoThumb extends MovieClip
	{
		
		private var _originalIndex:Number ;
		private var _originalX:Number ;
		private var _isOpened:Boolean = false;
		
		
		/**
		* Constructor
		*/
		public function VideoThumb(){}
		
		
		/**
		* Original Index position (usefull to know the Thumb depth)
		*/
		public function set originalIndex(val:Number):void {
			_originalIndex = val;			
		}
		
		public function get originalX():Number {
			return _originalX ;			
		}
		
		
		
		
		/**
		* Original x position (usefull to position Thumb to the original Position)
		*/
		public function set originalX(val:Number):void {
			_originalX = val;			
		}
		
		
		public function get originalIndex():Number {
			return _originalIndex ;			
		}
		
		
		
		
		/**
		* If the VideoThumb is opened or not
		*/
		public function set isOpened(val:Boolean):void {
			_isOpened = val;			
		}
				
		
		public function get isOpened():Boolean {
			return _isOpened ;			
		}
		
		
	}
}